EXCEL - I am trying to create a LOOKUP formula that returns the text
comments of other cells.  Because the formula asks for the results to
be typed into the formula itself in quotation marks, it is returning
the cell address not the cell contents.  This is what I have so far. 
I dont want to have to type the cell contents directly into the
formula so that I can paste the formula across several different
workbooks
=LOOKUP(D25,{1,2,3,4,5,6,7,8,9,10},{"(d5)","(e5)","(f5)","(g5)","(h5)","(i5)","(j5)","(k5)","(l5)","(m5)","(n5)"})

I'm not sure what you are trying to do.  The formula you have is for
several comments and just one cell.  If you are just trying to string
together the text comments in one cell with commas in between, why not
just type:

=d5&","&e5&","&f5&","&g5&","&h5&","&i5&","&j5&","&k5&","&l5&","&m5&","&n5

I too am not sure what you are trying to do. If you remove the
brackets around each of the 'addresses' in your second array and then
use INDIRECT around your function you can return the contents of the
nth address where n is between 1 and 10 given in D25
e.g.
=INDIRECT(LOOKUP(D25,{1,2,3,4,5,6,7,8,9,10},{"d5","e5","f5","g5","h5","i5","j5","k5","l5","m5","n5"}))

If this is what you wanted then a more straightforward way of
returning the nth value in a range of contiguous cells would be offset
e.g.
=OFFSET(D5,0,D25-1)
but then if your second array contained non-contiguous cells your
formula was nearly there

I think qac may have been correct in assuming what you are trying to
do.  If you are merely trying to choose one response from the cells d5
thru n5 based on a value in cell d25, use the CHOOSE function:

=CHOOSE(D25,D5,E5,F5,G5,H5,I5,J5,K5,L5,M5,N5)

If, for example, D25 has the value 5, the CHOOSE function will return
whatever is in cell H5, whether it is text or numerical.

Indicentally, d5 thru n5 is eleven cells, not ten.

You could use formula
=LOOKUP(D25,{1,2,3,4,5,6,7,8,9,10},D5:M5)

Please note that this will give correct response if D25 lies in range 1 through 10.